Files
spark/cmake/InstallBasic.cmake
T

62 lines
1.8 KiB
CMake

include_guard(DIRECTORY)
include(GNUInstallDirs)
include(${CMAKE_SOURCE_DIR}/cmake/PackBasic.cmake)
include(${CMAKE_SOURCE_DIR}/cmake/SetFirstDefined.cmake)
function(install_basic)
set(_options)
set(_one_value_args NAME INCLUDE_DIR BUILD_INCLUDE_DIR VERSION)
set(_multi_value_args)
cmake_parse_arguments(_ARGS "${_options}" "${_one_value_args}" "${_multi_value_args}" ${ARGN})
set_first_defined(_name _ARGS_NAME PROJECT_NAME)
set_first_defined(_include_dir _ARGS_INCLUDE_DIR _name)
set_first_defined(_build_include_dir _ARGS_BUILD_INCLUDE_DIR _name)
set(_base_dirs)
# Look for headers in source dir and build dir
set(_headers)
if (_include_dir)
list(APPEND _base_dirs "${CMAKE_CURRENT_SOURCE_DIR}")
file(
GLOB_RECURSE _headers
${CMAKE_CURRENT_SOURCE_DIR}/${_include_dir}/*.h
${CMAKE_CURRENT_SOURCE_DIR}/${_include_dir}/*.hpp
)
endif()
set(_build_headers)
if(_build_include_dir)
list(APPEND _base_dirs "${CMAKE_CURRENT_BINARY_DIR}")
file(
GLOB_RECURSE _build_headers
${CMAKE_CURRENT_BINARY_DIR}/${_build_include_dir}/*.h
${CMAKE_CURRENT_BINARY_DIR}/${_build_include_dir}/*.hpp
)
endif()
target_sources(
${_name}
PUBLIC
FILE_SET HEADERS
BASE_DIRS ${_base_dirs}
FILES
${_headers}
${_build_headers}
)
install(
TARGETS ${_name}
EXPORT ${_name}Targets
RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
FILE_SET HEADERS DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
)
install(
EXPORT ${_name}Targets
FILE ${_name}Targets.cmake
NAMESPACE ${_name}::
DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${_name})
pack_basic(NAME ${_name} VERSION "${_ARGS_VERSION}")
endfunction()