Files
spark/tools/spark.cmd
John Colvin 256f7025a2 tool: Run Spark.exe from its own directory
It looks in the working directory for runtime config appsettings.json files.
2025-11-15 12:38:48 -05:00

34 lines
840 B
Batchfile

@echo off
@REM Launch Spark.exe
@REM Usage: spark.cmd <spark_exe_args>
@REM Usage: spark.cmd [debug|release] <spark_exe_args>
setlocal
@REM Note: Evaluate %~dp0 before running SHIFT. Initially, it equals this
@REM script's parent dir. Once SHIFT is run, it changes to the working dir.
set REPO_DIR=%~dp0..
set BUILD_TYPE=Debug
@REM If the first arg is 'debug' or 'release', it indicates which Spark.exe to
@REM run (debug or release). All other args are passed to Spark.exe.
IF /I "%1"=="release" (
set BUILD_TYPE=Release
shift
) ELSE IF /I "%1"=="debug" (
shift
)
set SPARK_EXE_ARGS=%1
if "%1"=="" goto launch_spark
shift
:exe_args_loop
if "%1"=="" goto launch_spark
set SPARK_EXE_ARGS=%SPARK_EXE_ARGS% %1
shift
goto exe_args_loop
:launch_spark
cd %REPO_DIR%\build\%BUILD_TYPE%\bin\net8.0-windows\
Spark.exe %SPARK_EXE_ARGS%