cmake_minimum_required(VERSION 3.5)
project(Spark.Admin.WebApp)

include(${CMAKE_SOURCE_DIR}/cmake/safe_dep_glob.cmake)
include(${CMAKE_SOURCE_DIR}/cmake/Protobuf.cmake)

# dependencies
set(PROTO_GLOBS
  ../lib/api/*.proto
  ../lib/api/services/*.proto
  ../lib/domain_model/*.proto
  ../lib/sparkproto/*.proto
  ../lib/md/protos/*.proto
  ../../externals/linux/include/google/protobuf/descriptor.proto
  ../../externals/linux/include/google/protobuf/timestamp.proto)

file(
  GLOB_RECURSE _proto_rel_SOURCES
  RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
  ${PROTO_GLOBS})

file(
  GLOB_RECURSE _proto_abs_SOURCES
  ${PROTO_GLOBS})

file(
  GLOB_RECURSE _ts_SOURCES
  RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
  src/*.ts)

file(
  GLOB_RECURSE _fs_SOURCES
  RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
  src/*.fs)

set(_tools ${CMAKE_SOURCE_DIR}/tools)
set(_quiet_exec ${_tools}/quiet_exec.sh)
set(_venv_exec ${_tools}/venv_exec.sh)
set(_tools_py ${CMAKE_SOURCE_DIR}/tools/py)

# The tsconfig file is generated as a function of the cmake build type, and
# binary dir. Depending on the build type, it extends either
# 'tsconfig.debug.json' or 'tsconfig.release.json'.
set(_tsconfig_base "${CMAKE_CURRENT_SOURCE_DIR}/tsconfig.$<IF:$<CONFIG:Debug>,debug,release>.json")
set(WEBPACK_MODE $<IF:$<CONFIG:Debug>,"development","production">)
set(_tsconfig "${CMAKE_CURRENT_BINARY_DIR}/tsconfig.json")

set(_venv_python ${CMAKE_SOURCE_DIR}/.venv/bin/python)
set(_gen_tsconfig_py ${_tools_py}/gen_tsconfig.py)
set(_build_admin_web_app_py ${_tools_py}/build_admin_web_app.py)

set(_gen_tsconfig_deps ${_venv_exec} ${_venv_python} ${_gen_tsconfig_py} ${_tsconfig_base})

set(_build_admin_web_app_deps
  ${_quiet_exec}
  ${_venv_exec}
  ${_venv_python}
  ${_build_admin_web_app_py}
  ${CMAKE_CURRENT_SOURCE_DIR}/src/Spark.Admin.WebApp.fsproj
  ${CMAKE_CURRENT_SOURCE_DIR}/webpack.config.js
  ${CMAKE_SOURCE_DIR}/src/lib/api/service_compiler/templates/fs/fable.fs
  ${CMAKE_CURRENT_SOURCE_DIR}/package-lock.json
  ${_proto_rel_SOURCES}
  ${_api_ts_SOURCES}
  ${_ui_fs_SOURCES}
  ${_tsconfig})

update_deps_file("${_build_admin_web_app_deps}")

function(npm_install path)
  add_custom_command(
    OUTPUT ${path}/package-lock.json
    COMMAND "npm" ARGS "install"
    DEPENDS ${path}/package.json
    WORKING_DIRECTORY ${path}
    COMMENT "Run 'npm install' in ${path}")
endfunction()

npm_install(${CMAKE_CURRENT_SOURCE_DIR})

add_custom_command(
  OUTPUT ${_tsconfig}
  COMMAND ${_venv_exec}
  ARGS
  ${_venv_python}
  ${_gen_tsconfig_py}
  --config-base ${_tsconfig_base}
  --config-out ${_tsconfig}
  --build-out ${CMAKE_CURRENT_BINARY_DIR}
  DEPENDS ${_gen_tsconfig_deps})

add_custom_command(
  OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/bundle.js
  COMMAND ${_quiet_exec}
  ARGS
  ${_venv_exec}
  ${_venv_python}
  ${_build_admin_web_app_py}
  --protos ${_proto_abs_SOURCES}
  --tsconfig ${_tsconfig}
  --mode ${WEBPACK_MODE}
  --output-dir ${CMAKE_CURRENT_BINARY_DIR}
  COMMENT "Building Spark.Admin.WebApp"
  DEPENDS ${_build_admin_web_app_deps})

add_custom_target(admin_web_app_bundle ALL DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/bundle.js)

install(DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}" DESTINATION "${SPARK_INSTALL_PREFIX}/bin")
