cmake_minimum_required(VERSION 3.5)
project(web)

include(${CMAKE_SOURCE_DIR}/cmake/safe_dep_glob.cmake)
include(${CMAKE_SOURCE_DIR}/cmake/Protobuf.cmake)

# dependencies
set(PROTO_GLOBS
  ../lib/api/*.proto
  ../lib/api/services/*.proto
  ../lib/domain_model/*.proto
  ../lib/sparkproto/*.proto
  ../lib/md/protos/*.proto
  ../../externals/linux/include/google/protobuf/descriptor.proto
  ../../externals/linux/include/google/protobuf/timestamp.proto)

file(
  GLOB_RECURSE _proto_rel_SOURCES
  RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
  ${PROTO_GLOBS})

file(
  GLOB_RECURSE _proto_abs_SOURCES
  ${PROTO_GLOBS})

file(
  GLOB_RECURSE _api_ts_SOURCES
  RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
  api/src/*.ts)

file(
  GLOB_RECURSE _ui_fs_SOURCES
  RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
  ui/src/*.fs)

set(_tools ${CMAKE_SOURCE_DIR}/tools)
set(_quiet_exec ${_tools}/quiet_exec.sh)
set(_venv_exec ${_tools}/venv_exec.sh)
set(_tools_py ${CMAKE_SOURCE_DIR}/tools/py)

string(TOLOWER ${CMAKE_BUILD_TYPE} _build_type)
set(_tsconfig_base ${CMAKE_CURRENT_SOURCE_DIR}/api/tsconfig.${_build_type}.json)
set(WEB_TSCONFIG_NAME "last" CACHE STRING "Name for the generated tsconfig file")
set(_tsconfig "${CMAKE_CURRENT_SOURCE_DIR}/api/tsconfig.${WEB_TSCONFIG_NAME}.g.json")

set(_venv_python ${CMAKE_SOURCE_DIR}/.venv/bin/python)
set(_gen_tsconfig_py ${_tools_py}/gen_tsconfig.py)
set(_build_web_py ${_tools_py}/build_web.py)

set(_gen_tsconfig_deps ${_venv_exec} ${_venv_python} ${_gen_tsconfig_py} ${_tsconfig_base})

set(_build_web_deps
  ${_venv_exec}
  ${_venv_python}
  ${_build_web_py}
  ${CMAKE_CURRENT_SOURCE_DIR}/ui/src/ui.fsproj
  ${CMAKE_CURRENT_SOURCE_DIR}/ui/webpack.config.js
  ${CMAKE_SOURCE_DIR}/src/lib/api/service_compiler/templates/fs/fable.fs
  ${CMAKE_SOURCE_DIR}/src/web/api/package-lock.json
  ${_proto_rel_SOURCES}
  ${_api_ts_SOURCES}
  ${_ui_fs_SOURCES}
  ${_tsconfig})

update_deps_file("${_build_web_deps}")

function(npm_install path)
  add_custom_command(
    OUTPUT ${path}/package-lock.json
    COMMAND "npm" ARGS "install"
    DEPENDS ${path}/package.json
    WORKING_DIRECTORY ${path}
    COMMENT "Run 'npm install' in ${path}")
endfunction()

npm_install(${CMAKE_CURRENT_SOURCE_DIR}/api)
npm_install(${CMAKE_CURRENT_SOURCE_DIR}/ui)

add_custom_command(
  OUTPUT ${_tsconfig}
  COMMAND ${_venv_exec}
  ARGS
  ${_venv_python}
  ${_gen_tsconfig_py}
  --config-base ${_tsconfig_base}
  --config-out ${_tsconfig}
  --build-out ${CMAKE_BINARY_DIR}/web/api
  DEPENDS ${_gen_tsconfig_deps})

add_custom_command(
  OUTPUT ${CMAKE_BINARY_DIR}/web/ui/bundle.js
  COMMAND ${_quiet_exec}
  ARGS
  ${_venv_exec}
  ${_venv_python}
  ${_build_web_py}
  --protos ${_proto_abs_SOURCES}
  --tsconfig ${_tsconfig}
  --output-dir ${CMAKE_BINARY_DIR}/web
  COMMENT "Building Web UI"
  DEPENDS ${_build_web_deps})

add_custom_target(web_ui_bundle ALL DEPENDS ${CMAKE_BINARY_DIR}/web/ui/bundle.js)

install(DIRECTORY "${CMAKE_BINARY_DIR}/web" DESTINATION bin)
